[VisualBasic] Bestimmte Lines eines Textinhalts löschen

' Einzelne Zeile in eine Textdatei speichern
' sFilename: vollständiger Name der Datei
' LinePos : Zeilenummer in der Textdatei
' sLine : Inhalt, der gespeichert werden soll
' ===============================================
Public Sub txt_WriteLine(ByVal sFilename As String, _
 ByVal LinePos As Long, ByVal sLine As String)
 
 Dim F As Integer
 Dim N As Integer
 Dim I As Long
 Dim lRow As Long
 Dim Zeile As String
 Dim myTempFile As String
 
 If Dir$(sFilename, vbNormal) = "" Then
 ' Wenn Datei nicht existiert, automatisch erstellen
 ' und Inhalt sofort speichern
 F = FreeFile
 Open sFilename For Output As #F
 
 ' Datei mit Leerzeilen füllen, bis gewünschte
 ' Schreibposition erreicht ist
 For I = 1 To LinePos - 1
 Print #F, ""
 Next I
 
 ' Inhalt speichern
 Print #F, sLine
 Close #F
 
 Else
 ' Temporäre Datei erstellen
 myTempFile = txt_TempFilename()
 
 ' Original-Datei zum Lesen und temporäre
 ' Datei zum Schreiben öffnen
 F = FreeFile: Open sFilename For Input As #F
 N = FreeFile: Open myTempFile For Output As #N
 
 ' Original-Datei einlesen und x. Zeile durch
 ' neuen Inhalt ersetzen
 lRow = 0
 While Not EOF(F)
 lRow = lRow + 1
 Line Input #F, Zeile
 
 If lRow = LinePos Then
 ' x. Zeile durch neuen Inhalt ersetzen
 Zeile = sLine
 End If
 
 Print #N, Zeile
 Wend
 
 ' sollte LinePos größer sein, als die bisherige
 ' Anzahl gespeicherter Zeilen in der Orginaldatei
 ' wurde der neue Inhalt noch nicht gespeichert
 ' und die Datei muss ggf. noch mit zusätzlichen
 ' Leerzeilen gefüllt werden!
 If lRow < LinePos Then
 ' Ggf. mit Leerzeilen füllen
 For I = lRow + 1 To LinePos - 1
 Print #N, ""
 Next I
 
 ' Neuen Zeilen-Inhalt speichern
 Print #N, sLine
 End If
 
 ' Dateien schliessen
 Close #F: Close #N
 
 ' Alte Datei löschen
 Kill sFilename
 
 ' temporäre Datei in "alte" Datei umbenennen
 FileCopy myTempFile, sFilename
 Kill myTempFile
 End If
End Sub

Public Sub txt_DeleteLine(ByVal sFilename As String, ByVal lLineToDelete As Long)
 Dim F As Integer
 Dim N As Integer
 Dim sFileTemp As String
 Dim lCount As Long
 Dim sLine As String
 On Error Resume Next
 
 sFileTemp = sFilename & "~"
 
 F = FreeFile
 Open sFilename For Input As #F
 N = FreeFile
 Open sFileTemp For Output As #N
 
 While Not EOF(F)
 lCount = lCount + 1
 Line Input #F, sLine
 If lCount <> lLineToDelete Then
 Print #N, sLine
 End If
 Wend
 Close #F: Close #N
 
 Kill sFilename
 Name sFileTemp As sFilename
End Sub