[Code] VB6 ListView

'Dieser Quellcode stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'------------- Anfang Projektdatei Project1.vbp -------------
' Die Komponente 'Microsoft Windows Common Controls 5.0 (SP2) (comctl32.ocx)' wird benötigt.

'--------- Anfang Formular "Form1" alias Form1.frm ---------
' Steuerelement: Kontrollkästchen-Steuerelement "Check3"
' Steuerelement: Kontrollkästchen-Steuerelement "Check2"
' Steuerelement: Kontrollkästchen-Steuerelement "Check1"
' Steuerelement: Listenansichtsetuerelement "ListView1"

Option Explicit

Private Sub Form_Load()
 Dim x%

 With ListView1
 x = Int(.Width / 3.42)

 .ColumnHeaders.Add , , "Vorname und Name", x
 .ColumnHeaders.Add , , "Strasse und Hausnummer", x
 .ColumnHeaders.Add , , "Plz und Wohnort", x
 
 .View = lvwReport
 
 For x = 1 To 10
 .ListItems.Add , "Zeile " & x, Chr$(Rnd * 26 + 65) & _
 " Zeile " & (x - 1) & "...Spalte 1"
 
 .ListItems(x).SubItems(1) = Chr$(Rnd * 26 + 65) & " Zeile " _
 & (x - 1) & "...Spalte 2"
 
 .ListItems(x).SubItems(2) = Chr$(Rnd * 26 + 65) & " Zeile " _
 & (x - 1) & "...Spalte 3"
 Next x
 End With
End Sub

Private Sub Check1_Click()
 If Check1.Value = vbChecked Then
 ListView1.SortKey = 0
 ListView1.SortOrder = lvwAscending
 ListView1.Sorted = True
 End If
End Sub

Private Sub Check2_Click()
 Dim x%
 
 If Check2.Value = vbChecked Then
 ListView1.MultiSelect = True
 For x = 1 To 3
 ListView1.ListItems(x).Selected = True
 Next x
 
 ListView1.ListItems(7).Selected = True
 Else
 For x = 1 To ListView1.ListItems.Count
 ListView1.ListItems(x).Selected = False
 Next x
 
 ListView1.MultiSelect = False
 ListView1.ListItems(1).Selected = True
 End If
 ListView1.SetFocus
End Sub

Private Sub Check3_Click()
 If Check3.Value = vbChecked Then
 ListView1.HideColumnHeaders = True
 Else
 ListView1.HideColumnHeaders = False
 End If
 ListView1.SetFocus
End Sub

Private Sub ListView1_AfterLabelEdit(Cancel As Integer, _
 NewString As String)
 Dim x%
 
 x = MsgBox("Soll die geänderte Zelle wirklich " & _
 "übernommen werden?", vbYesNo)
 
 If x = 7 Then Cancel = 1
 ListView1.SetFocus
End Sub

Private Sub ListView1_BeforeLabelEdit(Cancel As Integer)
 Dim x%
 
 x = MsgBox("Wollen die Zelle wirklich editieren?", _
 vbYesNo)
 
 If x = 7 Then Cancel = 1
 ListView1.SetFocus
End Sub

Private Sub ListView1_ColumnClick(ByVal ColumnHeader As _
 ComctlLib.ColumnHeader)
 Me.Caption = ColumnHeader.Text

 If Check1.Value = vbChecked Then
 ListView1.SortKey = ColumnHeader.Index - 1
 If ListView1.SortOrder = lvwAscending Then
 ListView1.SortOrder = lvwDescending
 Else
 ListView1.SortOrder = lvwAscending
 End If
 ListView1.Sorted = True
 End If
End Sub

Private Sub ListView1_DblClick()
 Me.Caption = "DblClick: Text = '" & ListView1.SelectedItem.Text & _
 "' Key = '" & ListView1.SelectedItem.Key & _
 "' Index = '" & ListView1.SelectedItem.Index & "'"
End Sub

Private Sub ListView1_ItemClick(ByVal Item As ComctlLib.ListItem)
 Me.Caption = "Click: Text = '" & Item.Text & "' Key = '" & _
 Item.Key & "' Index = '" & Item.Index & "'"
End Sub
'---------- Ende Formular "Form1" alias Form1.frm ----------
'-------------- Ende Projektdatei Project1.vbp --------------