[Frage]ID3v1 oder ID3v2 Tagg mit Visual Basic auslesen

Dieses Thema im Forum "Programmierung & Entwicklung" wurde erstellt von weixi2, 30. Dezember 2004 .

Status des Themas:
Es sind keine weiteren Antworten möglich.
  1. Diese Seite verwendet Cookies. Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies. Weitere Informationen
  1. #1 30. Dezember 2004
    Hoi,

    ich hab damit angefangen einen MP§-Palyer zu coden.
    Bin auch schon weit.

    Aber wie kann ich den ID3v1 oder v2 Tagg bei den MP3's auslesen.

    Sonst hab ich keine Titelanzeige...


    wenns jemand weiss, dann postet es, gibt auch ne 10.

    MFG weixi2
     

  2. Anzeige
  3. #2 31. Dezember 2004
    Allgemein auslesen:

    Code:
    '------------- Anfang Projektdatei Projekt1.vbp -------------
    '--------- Anfang Formular "Form1" alias Form1.frm ---------
    ' Steuerelement: Kombinationsliste "Combo1"
    ' Steuerelement: Textfeld "txtGenreCode"
    ' Steuerelement: Textfeld "txtComment"
    ' Steuerelement: Textfeld "txtYear"
    ' Steuerelement: Textfeld "txtAlbum"
    ' Steuerelement: Textfeld "txtArtist"
    ' Steuerelement: Textfeld "txtTitle"
    ' Steuerelement: Beschriftungsfeld "Label8"
    ' Steuerelement: Beschriftungsfeld "Label6"
    ' Steuerelement: Beschriftungsfeld "Label5"
    ' Steuerelement: Beschriftungsfeld "Label4"
    ' Steuerelement: Beschriftungsfeld "Label3"
    ' Steuerelement: Beschriftungsfeld "Label2"
    ' Steuerelement: Beschriftungsfeld "Label1"
    
    Option Explicit
    
    Private Type TagInfo
     Tag As String * 3
     Songname As String * 30
     artist As String * 30
     album As String * 30
     year As String * 4
     comment As String * 30
     genre As String * 1
    End Type
    
    Dim FileName As String
    Dim CurrentTag As TagInfo
    
    Private Sub Form_Load()
     Dim temp As String
     On Error Resume Next
    
     FileName = App.Path & IIf(Right(App.Path, 1) = "\", "", "\") & _
     "myMP3.mp3"
    
     Open FileName For Binary As #1
     With CurrentTag
     
     Get #1, FileLen(FileName) - 127, .Tag
     If Not .Tag = "TAG" Then
     Label8.Caption = "No Tag"
     Close #1
     Exit Sub
     End If
     
     Get #1, , .Songname
     Get #1, , .artist
     Get #1, , .album
     Get #1, , .year
     Get #1, , .comment
     Get #1, , .genre
     Close #1
     
     txtTitle = RTrim(.Songname)
     txtArtist = RTrim(.artist)
     txtAlbum = RTrim(.album)
     txtYear = RTrim(.year)
     txtComment = RTrim(.comment)
     
     temp = RTrim(.genre)
     txtGenreCode = Asc(temp)
     Combo1.ListIndex = CInt(txtGenreCode) - 1
     End With
     Close #1
    End Sub
    '---------- Ende Formular "Form1" alias Form1.frm ----------
    '-------------- Ende Projektdatei Projekt1.vbp --------------
    ID3v1 lesen und schreiben:
    Code:
    '-------------- Anfang Projektdatei MP3Tag.vbp --------------
    ' Die Komponente 'Microsoft Common Dialog Control 6.0 (SP6) 
    ' (Comdlg32.ocx)' wird benötigt.
    ' Es muss ein Verweis auf 'Microsoft Scripting Runtime' gesetzt werden.
    '-------- Anfang Formular "frmTAG" alias frmTAG.frm --------
    ' Steuerelement: Standarddialog-Steuerelement "cdLoad"
    ' Steuerelement: Schaltfläche "cmdLoad"
    ' Steuerelement: Textfeld "txtGenere"
    ' Steuerelement: Textfeld "txtYear"
    ' Steuerelement: Textfeld "txtArtist"
    ' Steuerelement: Textfeld "txtComment"
    ' Steuerelement: Textfeld "txtAlbum"
    ' Steuerelement: Textfeld "txtTitle"
    ' Steuerelement: Schaltfläche "cmdSave"
    ' Steuerelement: Beschriftungsfeld "Label1"
    ' Steuerelement: Beschriftungsfeld "Label2"
    ' Steuerelement: Beschriftungsfeld "Label3"
    ' Steuerelement: Beschriftungsfeld "Label4"
    ' Steuerelement: Beschriftungsfeld "Label5"
    ' Steuerelement: Beschriftungsfeld "Label6"
    ' Steuerelement: Beschriftungsfeld "lblPath"
    Option Explicit
    Private Path$
    Private Sub cmdLoad_Click()
     Dim T As TagInfo
     cdLoad.ShowOpen
     Path = cdLoad.FileName
     If GET_ID3V1TAG(Path, T) Then
     txtAlbum.Text = T.album
     txtArtist.Text = T.artist
     txtComment.Text = T.comment
     txtGenere.Text = T.genre
     txtTitle.Text = T.Songname
     txtYear.Text = T.year
     
     Else
     txtAlbum.Text = ""
     txtArtist.Text = ""
     txtComment.Text = ""
     txtGenere.Text = ""
     txtTitle.Text = ""
     txtYear.Text = ""
     MsgBox "Kein ID3v1 Tag gefunden", vbInformation, "Info"
     End If
    End Sub
    
    Private Sub cmdSave_Click()
     Dim T As TagInfo
     T.album = txtAlbum.Text
     T.artist = txtArtist.Text
     T.comment = txtComment.Text
     T.genre = txtGenere.Text
     T.Songname = txtTitle.Text
     T.year = txtYear.Text
     If Not PUT_ID3V1TAG(Path, T) Then MsgBox "Fehler: Konnte keinen " & _
     "ID3v2 Tag schreiben", vbCritical, "Fehler"
    End Sub
    
    Private Sub Form_Load()
     cdLoad.Filter = "MP3-Dateien (*.mp3)|*.mp3"
    End Sub
    '--------- Ende Formular "frmTAG" alias frmTAG.frm ---------
    '---------- Anfang Modul "mdlMP3" alias mdlMP3.bas ----------
    '© by TEKER 2002
    
    Option Explicit
    
    Public Type TagInfo
     TAG As String * 3
     Songname As String * 30
     artist As String * 30
     album As String * 30
     year As String * 4
     comment As String * 30
     genre As String * 1
    End Type
    
    Public Path$, WINAMPPATH$
    
    Public Function GET_ID3V1TAG(FilePath$, TAG As TagInfo) As Boolean
     Dim FNum%, fso As New FileSystemObject
     On Error Goto ERRORS
     
     If Not fso.FileExists(FilePath) Then
     GET_ID3V1TAG = False
     Exit Function
     End If
     With TAG
     FNum = FreeFile
     Open FilePath For Binary As #FNum
     Get #FNum, LOF(FNum) - 127, .TAG
     If .TAG <> "TAG" Then
     GET_ID3V1TAG = False
     Close #FNum
     Exit Function
     End If
     Get #FNum, , .Songname
     Get #FNum, , .artist
     Get #FNum, , .album
     Get #FNum, , .year
     Get #FNum, , .comment
     Get #FNum, , .genre
     Close #FNum
     GET_ID3V1TAG = True
     End With
    
     Exit Function
    ERRORS:
     GET_ID3V1TAG = False
     Close #FNum
    End Function
    
    Public Function PUT_ID3V1TAG(FilePath$, TAG As TagInfo) As Boolean
     Dim FNum%, TPos&
     On Error Goto ERRORS
     
     With TAG
     FNum = FreeFile
     Open FilePath For Binary As #FNum
     TPos = LOF(FNum)
     Get #FNum, TPos - 127, .TAG
     If .TAG = "TAG" Then TPos = TPos - 127
     .TAG = "TAG"
     Put #FNum, TPos, TAG
     Close #FNum
     PUT_ID3V1TAG = True
     End With
    
     Exit Function
    ERRORS:
     PUT_ID3V1TAG = False
    End Function
    
    '----------- Ende Modul "mdlMP3" alias mdlMP3.bas -----------
    '--------------- Ende Projektdatei MP3Tag.vbp ---------------
    ID3v2 lesen und schreiben:
    Code:
    '------------- Anfang Projektdatei Projekt1.vbp -------------
    '--------- Anfang Formular "Form1" alias Form1.frm ---------
    ' Steuerelement: Textfeld "Text1"
    ' Steuerelement: Schaltfläche "Command1"
    ' Steuerelement: Beschriftungsfeld "Label2"
    ' Steuerelement: Beschriftungsfeld "Label1"
    
    Option Explicit
    
    Private Sub Command1_Click()
     Dim ID3Tag As ID3TagV2
     
     If GetID3TagV2(Text1.Text, ID3Tag) = True Then
     Label1.Caption = "Künstler: " & ID3Tag.Artist
     Label2.Caption = "Liedtitel: " & ID3Tag.Title
     End If
    End Sub
    '---------- Ende Formular "Form1" alias Form1.frm ----------
    '--------- Anfang Modul "Module1" alias Module1.bas ---------
    
    Option Explicit
    
    Public Type ID3TagV2
     Version As String
     TagLength As Long
     ExtendedHeader As Boolean
     PlayCounter As Long
     Track As Long
     Encoder As String
     Link As String
     Copyright As String
     OriginalArtist As String
     Composer As String
     Genre As String
     Comment As String
     Year As String
     Album As String
     Artist As String
     Title As String
     Language As String
     Length As Long
     MediaType As String
     Publisher As String
     DecodingSoftware As String
     UnknownFrames As Long
    End Type
    
    Public Function GetID3TagV2(ByVal MP3FileName As String, _
     ID3Tag As ID3TagV2) As Boolean
     
     Dim Mp3FileNumber, Mp3FileContent As String
     Dim ID3Position As Long, ID3Length As String, lngID3Length As Long
     Dim ID3Version As String, ID3V2Tag As String
     
     On Error Resume Next
     
     If Len(Dir(MP3FileName)) = 0 Then
     GetID3TagV2 = False
     Exit Function
     End If
     
     If LCase(Right(MP3FileName, 4)) <> ".mp3" Then
     GetID3TagV2 = False
     Exit Function
     End If
     
     Mp3FileNumber = FreeFile
     
     'MP3 einlesen...
     Open MP3FileName For Binary As Mp3FileNumber
     Mp3FileContent = String$(LOF(Mp3FileNumber), "!")
     Get Mp3FileNumber, , Mp3FileContent
     Close Mp3FileNumber
     
     'ID3V2-Tag suchen
     ID3Position = InStr(Mp3FileContent, "ID3")
     If ID3Position = 0 Then
     GetID3TagV2 = False
     Exit Function
     End If
     
     'Tag gefunden, weiter gehts!
     ID3Version = Mid$(Mp3FileContent, ID3Position + 3, 2)
     
     'Versionkontrolle
     If Asc(Left$(ID3Version, 1)) <> 2 And Asc(Left$(ID3Version, 1)) _
     <> 3 And _
     Asc(Left$(ID3Version, 1)) <> 4 Then
     
     GetID3TagV2 = False
     Exit Function
     End If
     
     'Version anzeigen
     ID3Tag.Version = Str$(Asc(Left$(ID3Version, 1))) & "." & _
     Trim$(Str$(Asc(Right$(ID3Version, 1))))
     
     'Länge bestimmen
     ID3Length = Mid$(Mp3FileContent, ID3Position + 6, 4)
     
     'lngID3Length = 256 * 8 * 8 * Asc(Left$(ID3Length, 1)) + 256 * 8 
    ' * Asc(Mid$(ID3Length, _
     2, 1)) + 256 * Asc(Mid$(ID3Length, 3, 1)) + _
     Asc(Mid$(ID3Length, 4, 1))
     
     
     lngID3Length = &H200000 * Asc(Left$(ID3Length, 1)) + &H4000 * _
     Asc(Mid$(ID3Length, _
     2, 1)) + &H80 * Asc(Mid$(ID3Length, 3, 1)) + _
     Asc(Mid$(ID3Length, 4, 1))
     
     
     'Länge ausgeben
     ID3Tag.TagLength = lngID3Length
     
     ID3V2Tag = Mid$(Mp3FileContent, ID3Position, lngID3Length + 10)
     
     Mp3FileContent = ""
     
     'Nach Extended Header suchen...
     If (Asc(Mid$(ID3V2Tag, 6, 1)) And 32) = 32 Then
     ID3Tag.ExtendedHeader = True
     ID3V2Tag = Mid$(ID3V2Tag, 10)
     End If
     ID3V2Tag = Mid$(ID3V2Tag, 11)
     
     'Nun Frame für Frame abarbeiten...
     Dim FrameName As String, FrameLen As String
     Dim FrameFlags As String, Frame As String
     Dim lngFrameLen As Long
     
     ID3Tag.UnknownFrames = 0
     
     Do
     
     'ID3V2.3
     If Asc(Left$(ID3Version, 1)) = 3 Or Asc(Left$(ID3Version, 1)) _
     = 4 Then
     
     'Frame-Header auslesen
     FrameName = Left$(ID3V2Tag, 4)
     
     'Wenn es sich um den Footer handelt, dann sind wir
     'fertig!
     If Left$(FrameName, 3) = "3DI" Then Exit Do
     FrameLen = Mid$(ID3V2Tag, 5, 4)
     lngFrameLen = 256 * 8 * 8 * Asc(Left$(FrameLen, 1)) + 256 _
     * 8 * Asc(Mid$(FrameLen, _
     2, 1)) + 256 * Asc(Mid$(FrameLen, 3, 1)) + _
     Asc(Mid$(FrameLen, 4, 1))
     
     
     
     FrameFlags = Mid$(ID3V2Tag, 9, 2)
     ID3V2Tag = Mid$(ID3V2Tag, 11)
     
     'Frame-Content bestimmen
     Select Case FrameName
     Case "PCNT"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.PlayCounter = Val(Mid$(ID3V2Tag, 2, _
     lngFrameLen - 1))
     Else
     ID3Tag.PlayCounter = Val(Left$(ID3V2Tag, lngFrameLen))
     End If
     
     Case "TRCK"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Track = Val(Mid$(ID3V2Tag, 2, lngFrameLen - 1))
     Else
     ID3Tag.Track = Val(Left$(ID3V2Tag, lngFrameLen))
     End If
     
     Case "TENC"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Encoder = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Encoder = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "WXXX"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Link = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Link = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCOP"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Copyright = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Copyright = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TOPE"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.OriginalArtist = Mid$(ID3V2Tag, 2, _
     lngFrameLen - 1)
     Else
     ID3Tag.OriginalArtist = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCOM"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Composer = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Composer = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCON"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Genre = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Genre = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "COMM"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Comment = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Comment = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TYER"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Year = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Year = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TALB"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Album = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Album = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TPE1"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Artist = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Artist = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TIT2"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Title = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Title = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TLAN"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Language = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Language = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TLEN"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Length = Val(Mid$(ID3V2Tag, 2, lngFrameLen - 1))
     Else
     ID3Tag.Length = Val(Left$(ID3V2Tag, lngFrameLen))
     End If
     
     Case "TMED"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.MediaType = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.MediaType = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TPUB"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Publisher = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Publisher = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TSSE"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.DecodingSoftware = Mid$(ID3V2Tag, 2, _
     lngFrameLen - 1)
     Else
     ID3Tag.DecodingSoftware = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case Else
     ID3Tag.UnknownFrames = ID3Tag.UnknownFrames + 1
     End Select
     
     ID3V2Tag = Mid$(ID3V2Tag, lngFrameLen + 1)
     
     'ID3V2.2
     ElseIf Asc(Left$(ID3Version, 1)) = 2 Then
     
     'Frame-Header auslesen
     FrameName = Left$(ID3V2Tag, 3)
     
     'Wenn es sich um den Footer handelt, dann sind wir
     'fertig!
     If FrameName = "3DI" Then Exit Do
     FrameLen = Mid$(ID3V2Tag, 4, 3)
     lngFrameLen = 256 * 8 * Asc(Left$(FrameLen, 1)) + 256 * _
     Asc(Mid$(FrameLen, 2, _
     1)) + Asc(Mid$(FrameLen, 3, 1))
     
     
     
     ID3V2Tag = Mid$(ID3V2Tag, 7)
     
     'Frame-Content bestimmen
     Select Case FrameName
     Case "TRK"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Track = Val(Mid$(ID3V2Tag, 2, lngFrameLen - 1))
     Else
     ID3Tag.Track = Val(Left$(ID3V2Tag, lngFrameLen))
     End If
     
     Case "TEN"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Encoder = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Encoder = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCR"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Copyright = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Copyright = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TOA"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.OriginalArtist = Mid$(ID3V2Tag, 2, _
     lngFrameLen - 1)
     Else
     ID3Tag.OriginalArtist = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCM"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Composer = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Composer = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TCO"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Genre = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Genre = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "COM"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Comment = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Comment = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TYE"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Year = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Year = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TAL"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Album = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Album = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TP1"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Artist = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Artist = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TT2"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Title = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Title = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TLA"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.Language = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.Language = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TMT"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.MediaType = Mid$(ID3V2Tag, 2, lngFrameLen - 1)
     Else
     ID3Tag.MediaType = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case "TSS"
     If Left$(ID3V2Tag, 1) = Chr$(0) Then
     ID3Tag.DecodingSoftware = Mid$(ID3V2Tag, 2, _
     lngFrameLen - 1)
     Else
     ID3Tag.DecodingSoftware = Left$(ID3V2Tag, lngFrameLen)
     End If
     
     Case Else
     ID3Tag.UnknownFrames = ID3Tag.UnknownFrames + 1
     End Select
     
     ID3V2Tag = Mid$(ID3V2Tag, lngFrameLen + 1)
     
     End If
     
     Loop Until Len(ID3V2Tag) = 0
     
     GetID3TagV2 = True
    End Function
    '---------- Ende Modul "Module1" alias Module1.bas ----------
    '-------------- Ende Projektdatei Projekt1.vbp --------------
    So, ich hoffe ich konnte dir damit weiter helfen! Viel Spass noch beim coden!

    Mfg Resus
     
  4. #3 31. Dezember 2004
    Danke!!!

    Du hast mir sehhhhr geholfen...

    10 für dich!!

    All done -> Closed
     

  5. Videos zum Thema
Die Seite wird geladen...
Similar Threads - Frage ID3v1 ID3v2
  1. Antworten:
    3
    Aufrufe:
    3.807
  2. Verständnisfrage zu React

    Decryptor , 11. März 2017 , im Forum: Webentwicklung
    Antworten:
    8
    Aufrufe:
    1.794
  3. Antworten:
    6
    Aufrufe:
    2.007
  4. Antworten:
    2
    Aufrufe:
    1.022
  5. Umfrage zu Anabole Steroide

    powerfull , 12. September 2016 , im Forum: Sport und Fitness
    Antworten:
    4
    Aufrufe:
    1.128